// DESCRIPTION
// This strategy slowly rolls out (and hides) the attributes of concepts based
// on how often a concept has been accessed. Conbcepts are monitored through
// the title attribute.
// Concept.beenthere keeps track of visits; Concepts have the label
// "showatmost" if they should disappear after a while (with weight indicating
// the number of visits required) and the label "showafter" if they should show
// up after a while (again, weight indicates the number of visits)

// VARS
// UM.GM.Concept.beenthere, GM.Concept.label, GM.Concept.weight

initialization(

  while true (
    UM.GM.Concept.beenthere = 0
    PM.GM.Concept.show = true
  )
  while GM.Concept.label == showafter (
    if GM.Concept.weight > 1 then (
      PM.GM.Concept.show = false
    ) else (
      PM.GM.Concept.show = true
    )
  )

)

implementation (

  if UM.GM.Concept.access == true then (
    UM.GM.Concept.beenthere += 1
  )

  if enough(UM.GM.Concept.beenthere >= GM.Concept.weight
            GM.Concept.label == showatmost
            ,2) then (
    PM.GM.Concept.show = false
  )

  if enough(UM.GM.Concept.beenthere >= GM.Concept.weight
            GM.Concept.label == showafter
            ,2) then (
    PM.GM.Concept.show = true
  )
)